脚本编程

Windows下bat批处理脚本使用telnet批量检测远程端口小记

Jager · 7月1日 · 2015年 · · · 11545次已读

多年没写过批处理了,来新公司的第一个 case 却是需要写一个 bat 脚本,批量更新采集 agent 的配置文件,其中就涉及到远程 IP 的端口检测。

本以为会和 Linux 一样可以简单判断:

echo q|telnet -e 'q' $ip $port && echo "$ip:port 通"||echo "$ip:port 不通"

结果发现 Windows 下面 telnet 退出并没有执行结果的返回值:

Windows下bat批处理脚本使用telnet批量检测远程端口小记

一、借助工具

于是我优先开启懒人法则,找其他替代工具。果然,在 Windows 老娘家找到了:

Portqryhttps://support.microsoft.com/en-us/kb/310099/zh-cn

确实可以使用,不过检测速度不敢恭维,通与不通都很慢!鉴于手头没有更好的解决办法,就先试试看,贴一下我写的 Portqry 相关 demo:

::使用微软官方工具【PortQry】进行检测的代码:
@echo off & setlocal enabledelayedexpansion

rem 要检测的 IP 和端口
set server_ip='192.168.1.1,192.168.1.2,192.168.1.3'
set serverport='9922'

rem 模块化调用
call :check

::****其他代码略****

:check
rem ※探测端口模块--PortQry 方案※
for /f  "tokens=1,* delims=," %%i in ("!server_ip!") do (
    echo 正在检测 %%i 的 !serverport! 端口...
    rem 这是关键的检测代码:
    "!tools_dir!\PortQry.exe" -n %%i -p tcp -e !serverport! | find "LISTENIN" >nul && (
        echo 【成功】:可以连接到 %%i:!serverport!
        ) || (
        echo 【失败】:无法连通 %%i:!serverport!
    )
    echo=
    set server_ip=%%j
    goto check
)
goto :eof  
::*******其他代码略********

Ps:check 是一个被 call 调用的模块,里面的一些变量就不做介绍了。

于是兴冲冲的封装成 exe,给 IDC(server2003 系统)执行,结果第一台就悲剧了!远程桌面直接断开了:

Windows下bat批处理脚本使用telnet批量检测远程端口小记

然后再也连不上了,要他们去机房看了下,结果告诉我系统没了!!??太震精了有木有?一个简单的文本操作脚本,居然把系统干掉了么?而且脚本中都不存在任何删除命令。。。

要那边提供了一下启动错误信息,原来是系统引导坏了:

Windows下bat批处理脚本使用telnet批量检测远程端口小记

个人分析了一下,应该是 Portqry 这个工具导致系统蓝屏关机,进而导致引导损坏!

尼玛,娘家人介绍时说好的“性格”良好呢?

Windows下bat批处理脚本使用telnet批量检测远程端口小记

唉,看来这个工具是不敢使用了,俗话说林子大了什么系统都有嘞!

二、另辟蹊径

既然工具不敢用了,还是继续折腾代码吧!周末睡觉前突然灵感一闪,想起了 tasklist 判断窗口名称这个“失传绝技”,于是把刚关闭的本子又打开,终于在 GF 的不断抱怨之下搞定了这个问题。

①、窗口判断

思路比较简单:使用 start 命令在新窗口执行 telnet -e 和 exit 命令,如果端口畅通,那么新开的窗口将会立即关闭,而不通的窗口则会保持近半分钟左右,且窗口名称类似 telnet 192.168.1.1,这半分钟时间足够脚本来判断通还是不通了。

于是将上面 check 部分修改如下:

::使用 telnet 命令检测的代码
@echo off & setlocal enabledelayedexpansion

rem 要检测的 IP 和端口
set server_ip='192.168.1.1,192.168.1.2,192.168.1.3'
set serverport='9922'

rem 模块化调用
call :check_port

::****其他代码略****

:check_port
rem ※探测端口模块--telnet 方案※
for /f  "tokens=1,* delims=," %%i in ("!server_ip!") do (
    echo [No.!check_num!]:正在检测 %%i 的 !serverport! 端口...  
    rem 新窗口打开 telnet,如果端口畅通会立即退出,脚本会在 3 秒后查看 telnet 窗口是否退出,如果没有退出表示端口不通!
    start /min cmd.exe /k "echo q|telnet -e 'q' %%i !serverport! & exit"
    ping -n 3 127.1>nul
    rem 查找窗口名为“Telnet ${ip}”的 cmd 窗口,如果存在则表示此 IP 不通
    tasklist /fi "windowtitle eq Telnet %%i" | find "cmd.exe" >nul && (
        echo 【失败】:无法连通 %%i:!serverport!
    ) || (
        echo 【成功】:可以连接到 %%i:!serverport!
    )
    echo=
    set server_ip=%%j
    goto check_port
)
goto :eof
::其他代码略...

样就解决了 Windows 下 telnet 探测远程端口的问题了,而且检测速度比微软哪个 portqry 快多了,果然思路比技术更重要,只要有想法,任何技术都不应该成为瓶颈!

②、进程判断【最新补充

当使用窗口判断的方案下发各大机房实施的时候,又一个问题出现了!窗口判断在某些版本的 Windows 下是行不通的,比如英文版下的命令提示符窗口名称和中文版的就不一样,所以这个方案也是不完善的!

于是,继续抓耳挠腮,想出了第二个方案:通过判断 telnet 进程数量来判断网络是否畅通。

方案思路:

a. 先判断脚本执行之前是否存在 telnet.exe 的进程,如果存在则统计数量

b. 和窗口判断一样,利用 start 命令在新的 cmd 命令提示符中执行 telnet 命令

c. 延迟几秒后统计系统中存在的 telnet.exe 进程数(存在的 telnet 表示是不通的)

d. 和最开始统计的 telnet 进程数比对计算,就知道有几个 IP 是不通的了

示例代码:

::使用 telnet 命令检测的代码
@echo off & setlocal enabledelayedexpansion

rem 要检测的 IP 和端口
set server_ip='192.168.1.1,192.168.1.2,192.168.1.3'
set serverport='9922'

::****其他代码略****
rem 刚开始先计算 telnet.exe 的进程数量,避免脚本执行之前就已经存在 telnet.exe
call :telnet_num conf

rem 模块化调用
call :check_port

:check_port
set /a check_num+=1
rem ※探测端口模块※
for /f  "tokens=1,* delims=," %%i in ("!server_ip!") do (
	echo [No.!check_num!]:正在检测 %%i 的 !serverport! 端口...
	::call :set_iPSec %%i
	rem 使用 telnet 组合命令进行测试,如果端口畅通会立即退出,脚本会在 3 秒后查看 telnet 窗口是否退出,如果没有退出表示端口不通!
	start /min cmd.exe /k "echo q|telnet -e 'q' %%i !serverport! & exit"
	echo=
	set server_ip=%%j
	set total_num=!check_num!
	goto check_port
)

ping -n 3 127.1>nul

#再次计算 telnet 进程数量,而且已经排除执行之前就有的 telnet 数量
call :telnet_num

echo 可用数量为:!telnet_num!
goto :eof

:telnet_num
rem 检测 telnet 进程数量,已排除脚本之前存在 telnet
set conf=0
for /f "delims=*" %%i in ('tasklist ^| findstr "telnet.exe"') do (
	if "%1"=="conf" (
		set /a conf+=1
	) else (
		set /a telnet_num+=1
	)	
)
set /a telnet_num=!telnet_num!-!conf!
goto :eof

 

很明显,这样就可以知道我测试了所有 IP 当中有几个是不通的了。遗憾的是无法知道是哪个 IP 不通。不过在手头的这个 case 当中是不需要具体不通的 IP 的,只要知道通的 IP 是否达标就行。

好了,终于把这个问题给解决了。显然,任何时候都需要给出多个方案,而不是自满于一个方案。否则出问题就会焦头烂额了。当然,再次说明了想法比技术更重要。

21 条回应
  1. 雪鹰领主 2015-7-1 · 22:04

    技术帝就是厉害,顶礼膜拜了

  2. unmn 2015-7-2 · 2:37

    只能说牛B,不能再用其它语言表达。

  3. 威客任务 2015-7-2 · 9:18

    就我现在的水平实在插不上嘴,我才知道表单提交的的说,慢慢来,总会有一天能和大神一起交流的

  4. 厘米天空 2015-7-2 · 22:06

    我来坐沙发,看来搞运维批处理必须掌握啊!

  5. 胡歌网摘 2015-7-6 · 18:45

    用Python……

    • avatar
      Jager 2015-7-6 · 22:07

      py是可以,但需要额外安装环境支持。给客户的东西使用越简单越好。

      • f 2017-2-5 · 10:28

        只要額外安裝,就有風險,萬一安裝python出了問題,又是一大輪折騰

  6. 青春励志语录 2015-7-8 · 15:30

    青春励志语录www.qclzyl.com博主的文章非常精彩,向博主学习~ 希望能和博主交换链接~

  7. 暴赚金 2015-7-14 · 12:02

    谢谢分享 搜来的

  8. 大老鹰2015 2015-7-16 · 11:27

    talnet命令号强大的说

  9. 27joy.cn耕耘网 2015-8-18 · 13:47

    老哥,你的网站车震效果很猛啊,搞得我心颤抖,还有点小鸡冻 :mrgreen:

  10. copdips 2015-10-3 · 16:14

    telnet只能tcp,udp还是不行啊

    • avatar
      Jager 2015-10-3 · 22:30

      仔细看一看文章,portqry方案支持-p udp 参数,另外netcat也可以检测udp端口,自行百度看看。

      • copdips 2015-10-3 · 23:32

        你说portqry不好用,所以我就单看telnet了。最好的办法还是你说的netcat nmap之类感觉

  11. f 2017-2-5 · 10:29

    有什麼辦法可以隱藏彈出來的Telnet窗口,想讓他後台執行

  12. wenyu 2017-3-22 · 1:10

    for /l %i in (1,1,254) do ping -n 1 10.10.10.%i 输出文件,可以试试

    • avatar
      Jager 2017-3-22 · 9:57

      啥?文章说的是telnet测试端口是否通,不是能否ping通

      • wenyu 2017-3-22 · 10:17

        全ping一遍,然后arp 可以看到那些机子存活,然后再进行后面的事情不是简单多了,有的机子禁ping,但是ping完以后arp 是有记录的。

        • avatar
          Jager 2017-3-23 · 13:12

          不是存不存活的问题,这些机器都存在,只是防火墙策略或网络链路不通,需要telnet测试的问题。

  13. slzzz 2019-6-26 · 14:52

    这个场景用golang很合适